Modify a text file: $/bam-tiles.01a.pde

$/bam-tiles.01a.pde

//// Tile puzzle.
//// Move tiles to get solution.

String title="Move tiles to answer the question.";
String author="ProfessorBAM";
String question="What color is the sun?";
String answer="YELLOW";
char[] letters={ 'W', 'O', 'L', 'L', 'E', 'Y' };

int many=6, pick=-1, drop=-1;
Tile[] tiles = new Tile[many];
int left=50, spacing=100, top=300;
int tileWidth=80, tileHeight=80;

color BLACK=0, WHITE=#FFFFFF, GRAY=#999999,
  RED=#FF0000, GREEN=#00FF00, BLUE=#0000FF, 
  YELLOW=#FFFF00, CYAN=#00FFFF, MAGENTA=#FF00FF;

void setup() {
  size( 750, 600 );
  int x=left, y=top;
  // ++ Calculate positions based on many ++
  for (int i=0; i<many; ++i) {
    tiles[i]=  new Tile( letters[i], x, y );
    x += spacing;
  }
}

void draw() {
  background(WHITE);
  messages();
  for (int i=0; i<many; ++i) {
    if (i==pick) {
      tiles[i].show( mouseX, mouseY );
    }
    else
    {
      tiles[i].show();
    }
  }
}
void messages() {
  fill(BLACK);
  textSize(30);
  text( question, width/3, 100 );
  textSize(12);
  fill(BLUE);
  text( title, 20, 40 );
  text( author, 20, height-20 );
}

class Tile {
  int x, y, w=tileWidth, h=tileHeight;
  char c='?';
  
  //// CONSTRUCTOR(S):
  Tile( char c, int x, int y ) {
    this.c=c;
    this.x=x;
    this.y=y;
  }
  
  //// METHODS:
  void show() {
    show(x,y);      // Display tile in place.
  }
  void show( float x, float y) {
    fill(BLACK);
    rect( x,y, w,h, 6 );    // (round corners)
    fill(YELLOW);
    textSize(36);
    text( c, x+w/3, y+h*2/3);
  }
  boolean clicked() {
    return hit( mouseX, mouseY );
  }
  boolean hit( float x2, float y2 ) {
    if (x2<x || x2 > x+w) return false;
    if (y2<y || y2 > y+h) return false;
    return true;    
  }
  boolean hover( float x2, float y2 ) {
    if (x2>x-w/2 && x2<x+w/2) return true;
    return false;
  }
}

//// EVENT HANDLERS ////
void mousePressed() {
  for (int i=0; i<many; ++i) {
    if (tiles[i].clicked()) pick=i;
  }
}
void mouseReleased() {
  drop=-1;
  if (pick<0) return;
  // check mouseX, then calculate replace (if any).
  if (mouseX<left) return;
  for (int i=0; i<many; ++i) {
    if (tiles[i].hover(mouseX,mouseY)) drop=i;
  }
  if (drop>=0 && drop != pick) {
    // Swap tiles[drop] with tiles[pick];
    char what=  tiles[pick].c;
    tiles[pick].c = tiles[drop].c;
    tiles[drop].c = what;
  }
  pick = -1;      // (No more picked tile.)
}